MCM Script help

[RoyBatterian]

I'm trying to make an FOV Slider for MCM. I have the option in the MCM Configuration Menu, but the main setting won't show up. I can't figure out what I'm doing wrong, I've tried several different things, looked at other menu's as a last resort and I just don't know what the issue is.

 

Here's my script... some help would be appreciated.

 

 

scriptname FOVSliderConfigScript

short iMaster
short iMouseover
short iOption
float DefaultFOV
float CurrentFOV
float fDelay
float fValue
reference rList

begin GameMode

    if GetGameRestarted
        if IsModLoaded "The Mod Configuration Menu.esp"
            set iMaster to GetModIndex "The Mod Configuration Menu.esp"
            set rList to BuildRef iMaster 2790
            ListAddForm rList MCMFOVSliderItem
        endif
        
    elseif fDelay !=0.5
        set fDelay to 0.5
        SetQuestDelay FOVSliderConfig fDelay
    endif

end

begin MenuMode 1013

    if IsModLoaded "The Mod Configuration Menu.esp"
    else
        Return
    endif
    
    if fDelay != 0.01
        set fDelay to 0.01
        SetQuestDelay FovSliderConfig fDelay
    endif

    if GetUIFloat "StartMenu/MCM/_ActiveMod" == GetModIndex "FOV Slider"
        set iOption to GetUIFloat "StartMenu/MCM/_ActiveOption"
        set fValue to GetUIFloat "StartMenu/MCM/_Value"

        if GetUIFloat "StartMenu/MCM/_Reset"                ;1 - RESET
            SetUIFloat "StartMenu/MCM/_Reset" 0
            SetUIFloat "StartMenu/MCM/*:1/_columns" 1
            
            SetUIFloat "StartMenu/MCM/*:1/*:1/_enable" 1
            SetUIString "StartMenu/MCM/*:1/*:1/_title" "Field Of View"
            SetUIFloat "StartMenu/MCM/*:1/*:1/_type" 2
            SetUIFloat "StartMenu/MCM/*:1/*:1/_value" CurrentFOV

        elseif GetUIFloat "StartMenu/MCM/_Default"            ;2 - DEFAULT
            SetUIFloat "StartMenu/MCM/_Default" 0
            SetUIFloat "StartMenu/MCM/_Reset" 1
            
            set DefaultFOV to 70
            SetNumericIniSetting "fDefault1stPersonFOV:display" DefaultFOV
            set CurrentFOV to DefaultFOV
            SetCameraFOV CurrentFOV
            
        elseif GetUIFloat "StartMenu/MCM/_ShowList" == 1        ;4 - SHOW LIST
            SetUIFloat "StartMenu/MCM/_ShowList" 2
                
        elseif GetUIFloat "StartMenu/MCM/_ShowScale" == 1        ;5 - SHOW SCALE
            SetUIFloat "StartMenu/MCM/_ShowScale" 2

            if iOption == 1
                SetUIFloat "StartMenu/MCM/_Value" CurrentFOV
                SetUIFloat "StartMenu/MCM/_ValueDecimal" 3
                SetUIFloat "StartMenu/MCM/_ValueIncrement" 1
                SetUIFloat "StartMenu/MCM/_ValueMax" 180
                SetUIFloat "StartMenu/MCM/_ValueMin" 70
                SetUIString "StartMenu/MCM/*:2/_title" "Field of View"
                set CurrentFOV to fValue
                SetCameraFOV CurrentFOV
                setNumericIniSetting "fdefault1stpersonfov:display" CurrentFOV
            endif

        elseif GetUIFloat "StartMenu/MCM/_DefaultScale"        ;6 - DEFAULT SCALE
                SetUIFloat "StartMenu/MCM/_DefaultScale" 0
                SetUIFloat "StartMenu/MCM/_ShowScale" 2

            if iOption == 1
                SetUIFloat "StartMenu/MCM/_Value" 70
                set CurrentFOV to DefaultFOV
                SetCameraFOV CurrentFOV
                setNumericIniSetting "fdefault1stpersonfov:display" CurrentFOV
            endif
        endif

        if iMouseover != GetUIFloat "StartMenu/MCM/*:1/_optionID"        ;7 - MOUSE-OVER
            set iMouseover to GetUIFloat "StartMenu/MCM/*:1/_optionID"
            if iMouseover
                SetUIFloat "StartMenu/MCM/MCM_Info/visible" 1

                if iMouseover == 1
                    SetUIString "StartMenu/MCM/*:1/string" "Adjusts the current 1st person Field of View"
                else
                    SetUIFloat "StartMenu/MCM/*:1/visible" 0
                endif
            else
                SetUIFloat "StartMenu/MCM/MCM_Info/visible" 0
            endif
        endif

    endif
end

[luthienanarion]

if GetUIFloat "StartMenu/MCM/_ActiveMod" == GetModIndex "FOV Slider"

 

You must pass the entire filename to GetModIndex.

 

if GetUIFloat "StartMenu/MCM/_ActiveMod" == GetModIndex "FOV Slider.esp"

[RoyBatterian]

Thank you luthienanarian, now I can go about debugging it's functionality instead of struggling with getting it to show up.

 

Hehe