Help with MCM an Script Problem

[hitman47101]

Hey guys and gals.

 

I am making an MCM menu in a mod for personal use, it was going quite well but I've hit a small problem.

 

http://t.imgbox.com/axbZRa8i.jpg http://t.imgbox.com/tT0L4qbq.jpg

 

As you can see, its not displaying the Key i select in menu for the options after the first, it works perfectly in that i can change the hotkeys but it won't display what i changed them too like it does with the first one.

 

Here is the script:

 

 

  Reveal hidden contents

 

scn aaaRSAMCMScript

short iMaster
short iMouseover
short iOption
short iTemp
float fTemp
float fValue
reference rList

begin GameMode
    if GetGameRestarted
        if IsModLoaded "The Mod Configuration Menu.esp"
            set iMaster to GetModIndex "The Mod Configuration Menu.esp"
            set rList to BuildRef iMaster 2790
            ListAddForm rList aaaRSAMCMItem
        endif
    endif

end

begin MenuMode 1013
    if IsModLoaded "The Mod Configuration Menu.esp" == 0
        Return
    endif

    if GetUIFloat "StartMenu/MCM/_ActiveMod" == GetModIndex "R&S_InnovativeMod.esp"
        set iOption to GetUIFloat "StartMenu/MCM/_ActiveOption"
        set fValue to GetUIFloat "StartMenu/MCM/_Value"

        if GetUIFloat "StartMenu/MCM/_Reset"
            SetUIFloat "StartMenu/MCM/_Reset" 0

            SetUIFloat "StartMenu/MCM/*:1/_columns" 1

            SetUIFloat "StartMenu/MCM/*:1/*:1/_enable" 1
            SetUIString "StartMenu/MCM/*:1/*:1/_title" "Optic sight color Hotkey"
            SetUIFloat "StartMenu/MCM/*:1/*:1/_type" 3
            SetUIStringEx "StartMenu/MCM/*:1/*:1/value/*:1/string" "%k" aaaOpticColorKey

            SetUIFloat "StartMenu/MCM/*:1/*:2/_enable" 1
            SetUIString "StartMenu/MCM/*:1/*:2/_title" "Aiming mode/Attach Suppressor Hotkey"
            SetUIFloat "StartMenu/MCM/*:1/*:2/_type" 3
            SetUIStringEx "StartMenu/MCM/*:2/*:1/value/*:1/string" "%k" aaaAaimingModeKey

            SetUIFloat "StartMenu/MCM/*:1/*:3/_enable" 1
            SetUIString "StartMenu/MCM/*:1/*:3/_title" "laser sight Hotkey"
            SetUIFloat "StartMenu/MCM/*:1/*:3/_type" 3
            SetUIStringEx "StartMenu/MCM/*:3/*:1/value/*:1/string" "%k" aaaLaserSightKey

            SetUIFloat "StartMenu/MCM/*:1/*:4/_enable" 1
            SetUIString "StartMenu/MCM/*:1/*:4/_title" "Tac-Light Hotkey"
            SetUIFloat "StartMenu/MCM/*:1/*:4/_type" 3
            SetUIStringEx "StartMenu/MCM/*:4/*:1/value/*:1/string" "%k" aaaTACLightKey

        elseif GetUIFloat "StartMenu/MCM/_NewValue"
            SetUIFloat "StartMenu/MCM/_NewValue" 0
            SetUIFloat "StartMenu/MCM/_Reset" 1

            if iOption == 1
                    set aaaOpticColorKey to fValue
            elseif iOption == 2
                    set aaaAaimingModeKey to fValue
            elseif iOption == 3
                    set aaaLaserSightKey to fValue
            elseif iOption == 4
                    set aaaTACLightKey to fValue

            endif

        elseif GetUIFloat "StartMenu/MCM/_ShowList" == 1
            SetUIFloat "StartMenu/MCM/_ShowList" 2

                endif

        if iMouseover != GetUIFloat "StartMenu/MCM/*:1/_optionID"
            set iMouseover to GetUIFloat "StartMenu/MCM/*:1/_optionID"
            if iMouseover
                SetUIFloat "StartMenu/MCM/MCM_Info/visible" 1

                if iMouseover == 1
                    SetUIString "StartMenu/MCM/*:9/string" "Set a custom hotkey"
                elseif iMouseover == 2
                    SetUIString "StartMenu/MCM/*:9/string" "Set a custom hotkey"
                elseif iMouseover == 3
                    SetUIString "StartMenu/MCM/*:9/string" "Set a custom hotkey"
                elseif iMouseover == 4
                    SetUIString "StartMenu/MCM/*:9/string" "Set a custom hotkey"

                endif
            else
                SetUIFloat "StartMenu/MCM/MCM_Info/visible" 0
            endif
        endif        
    endif
end

 

 

 

Sorry for my awful scripting, i am still very new to this kind of scripting

 

I'm sure i can figure it out eventually, but any help would be very appreciated.

 

Thanks for taking a look. :smile:

 

Edit: sorry for the messed up title, didn't catch that until it was to late.

[jazzisparis]

You misplaced the indexes:

 

SetUIStringEx "StartMenu/MCM/*:2/*:1/value/*:1/string" "%k" aaaAaimingModeKey

Should be:

SetUIStringEx "StartMenu/MCM/*:1/*:2/value/*:1/string" "%k" aaaAaimingModeKey

 

(Same with 3 and 4)

[hitman47101]

Woohoo that worked perfectly!

 

No idea how i missed that. haha

 

Thank you so much!