Skyrim Lycanthropy Cure using the console

[kittytoaster]

Hi

I had trouble with curing my characters lycanthropy because of questline bugs.

The simple fix:
player.setstage F6090 100

If this doesn't work, try the following (lines in italic are lines of console code):

1. player.setstage F6090 0
2. Save the game
3. Quit to main menu
4. Load the game you just saved
5. player.setstage F6090 100
6. set PlayerIsWerewolf to 0

Additional info:

Alternatively you can replace steps 2 through 4 by leaving your current cell (entering another room).

Mind you, if you have the Lovers Stone active (XP bonus), you cannot get the well rested perk.

Some players don't get the well rested perk after using this fix when sleeping in their own homes, specifically in Breezehome in Whiterun, while they do get the well rested perk when sleeping in inn's etc. This also happens when curing your character without the use of the console. Was hoping to leave it for the Creation Kit, but as it's only released in January and the world ends by 2012, I'll have to get to the bottom of this without the Kit.

If you have cured your characters lycanthropy during the in-game questline but the 'Days as a werewolf' counter on your stats screen keeps rolling, step 6 might do the trick.

Confirmed to work before and after completing the Companions main questline. Confirmed that you can become a Vampire after being cured from lycanthropy.

Forcing lycanthropy using the console:

This is kind of blunt at the moment and just blunt-forcing the actual quest for becoming a werewolf to progress. Forcing lycanthropy this way only forces the benefits, you still get Rested perks from sleeping.
Mind you, none of the steps should be skipped.

1. player.addspell 92C48
2. select Beast Form as the active shout from your magic menu
3. use Beast Form and allow the transformation to finish (it's nto finished before yo ucan move your character)
4. player.setstage 2ba16 0
5. close the console and wait for 3 to 5 seconds
6. player.setstage 2ba16 1
7. close the console and wait for 3 to 5 seconds
8. player.setstage 2ba16 10
9. player.setstage 2ba16 11
10. player.setstage 2ba16 20
11. close the console and wait for 3 to 5 seconds
12. player.setstage 2ba16 100
13. close the console and allow your char to turn back into human form
14. player.addspell a1a3e
15. set playeriswerewolf to 1

Apart from getting the Rested perks, your char should be identical to a natural werewolf. Using the werewolf cure still works.

Forcing vampirism using the console:

I haven't found an easy way to skip to an advanced stage of vampirism straight away so I advise just adding the disease and then waiting.

1. ResetQuest eafd5
2. player.addspell b8780
3. Repeat step 2 until the last three lines in the console are: GetIsID, WornHasKeyWord and Spell 'Sanguine Vampiris' added to...

The player hasn't contracted the disease until the ID and keyword check have been done, even if the console confirms that the disease has indeed been added. You can confirm this by checking your characters active effects. Sanguine Vampiris should be there before you continue.

4. Wait for 72 hours.
5. Move a bit.

If your character sports a weird purple-bluish glow after becoming a vampire, just wait for another 24 hours to increase the vampirism stage and the glow should disappear for good.

Curing vampirism via the console:

1. player.resetstage eafd5
2. player.setstage eafd5 10

Unlike lycanthropy, they managed not to go overly dramatic, crazy and dumb with the vampirism cure script. If you want to become a vampire again after being cured, just do resetquest eafd5 and the block is lifted.

Additional information on vampirism:

Sometimes ebony shields and maybe other items become invisible after becoming a vampire. As far as I'm concerned, this issue does not make any sense as the vampirism is scripted clean and none of the variables have connections. It's confirmed that the shields become visible again after being cured.
It might be possible that becoming a vampire again after being cured doesn't raise this issue, in theory.

It's possible to be a "vampirewolf". First you need to contract vampirism and become a vampire. Then just add the 'beast form' spell and the 'werewolf abilities' spell and set the global variable playeriswerewolf to 1.

Disabling the Fur-in-your-ears guard dialogue using the Creation Kit:

To fix the guard commenting issue, all you have to do is get yourself the Creation Kit and mod the game a bit. If you don't know how to operate the Kit, you should take a look at the tutorials. If you feel comfortable with the kit already here's a quick tut on how to disable those comments.
After you've loaded the master file, goto Edit>Find text and search for 'out of your ears'. there should only be one result. Double click on the result (or Info text). this will open the Quest dialog for DialogueGuardsGeneral and highlight the fur out of ears dialogue line.
As you can see from the table, the conditions are stupid: the first part (GetStageDone) checks whether you've gone past the point in the companions questline where you become a werewolf and the second part GetInFaction checks whether the speaker is in fact a guard, not just a random person.
What Bethie did wrong, was leave out the part where it should check whether the player is a werewolf or not.

To fix this, doubleclick on the line in the table and this will open the dialogue editing dialog. Now find the table with the conditions and click on the 'New' button below it. From the Condition function dropdown menu select GetGlobalValue. Now click on the Parameters button labeled 'INVALID' and from the list, find 'PlayerIsWerewolf'. After clicking them OK's, the condition is addedto the list. Now the game checks for the global value to be positive before commanding the guards to talk such rubbish. You can also fix other comments like that, note that most of the werewolf comments are bunched up in the quest table.

A trick you could also do if you're a vampwolf, is that instead of selecting 'PlayerIswerewolf' you could choose PlayerIsVampire and set the target to 0.0000 instead of 1.0000. This way you wont get the furry comments when you're a vampire.

Using the same method described above, you can disable all annoying comments. To completely disable a line of random dialogue, add a GetIsID condition with the subject being the player. That way the dialog would only be spoken by the player, but as the player is a silent character, there wont be any dialogue at all.

Note that using the console for any of this might break any questlines. When forcing quests to start or end, you might skip importand initial and post-stage scripts and important variables might not get set. In addition for quest breaking, this might bring forth a number of engine related problems, including unexpected savegame bloating and active memory issues.
Try to avoid using the console when possible.

Now that the Creation Kit is out I don't feel like creating a fix for common issues. Some of the problems have deeper roots than the quest conditions, scripts and effects and the others are easy enough to be fixed by just about anyone to their preferences. If you need help fixing lycanthropy issues with the Creation Kit, I can guide you, but I won't release any mods myself.

Please leave a reply whether or not it worked for you or if you need help regarding lycanthropy and vampirism glitches.

Edited February 11, 2022 by kittytoaster

[silvalinionisis]

Didn't work for me. Still can't get any resting bonus. But since i cured it through normal ways, i can get contracted disease, meaning the lycanthropy cure quest removes your beast form and disease immunity and keeps the all disadvantages of lycanthropy.

 

edit: also i still count as a werewolf according to the general stats screen.

Edited November 20, 2011 by silvalinionisis

[kittytoaster]

Try this:

 

setstage F6090 0

 

*save and exit to main menu and load the same savegame*

 

setstage F6090 100

 

It looks as if you've been hit by a small memory error, having the cure quest fail to actually cure your lycanthropy. the setstage F6090 100 probably didnt wrok for you because after curing yourself in game the stage was already set to 100 and the setstage command always checks the current stage before apply'ing and cancels all action if current = target.

 

Hope it helped.

 

edit: Test results by sleeping. The flags and counters used in the stats screen are not as reliable and don't affect real gameplay.

Edited November 21, 2011 by kittytoaster

[silvalinionisis]

It worked alright but first i had to change my stone power. I had lover stone active all along, maybe that created the problem i don't know.

 

However, THANK YOU MAN!

 

edit: just remembered something else. I tried setting it to 0 then 100 but i didn't leave the area i was in. This time i left the area to change my stone power. Rather than loading the game, leaving the area might be the solution after using the first console command.

Edited November 21, 2011 by silvalinionisis

[Botoden]

Holy hell thank you for the "0-100" tip, I was about to pull my hair out and kick small animals. Thank you so much, now I can be the vampire I was ment to be now that the pesky cure werewolf(ism) glitch has been rectified. :tongue:

[kittytoaster]

edit: just remembered something else. I tried setting it to 0 then 100 but i didn't leave the area i was in. This time i left the area to change my stone power. Rather than loading the game, leaving the area might be the solution after using the first console command.

 

Thanks for the reply, wouldn't have guessed changing cells might force the game to re-evaluate the stats. Way easier than saving, exiting and reloading.

[Hayt89]

For those of you that say it's resolved using the 0-100 tip does that stop the General Stats counter from counting up Days as a Werewolf?

 

edit: I can get diseases and rested (so long as I'm not The Lover sign) but my days as Werewolf continue to go up.

Edited November 23, 2011 by Hayt89

[kittytoaster]

For those of you that say it's resolved using the 0-100 tip does that stop the General Stats counter from counting up Days as a Werewolf?

 

Thanks for bringing this up.

The counter didn't stop even when curing lycanthropy without using the console. This might be intentional, which would translate the real meaning of the coutner to 'days since contracting lycanthropy'. If not, it's just a bug.

 

To stop the counter type this into the console:

set PlayerIsWerewolf to 0

 

The counter uses the global variable to calculate the time.

I've also added this to the first post.

Edited November 23, 2011 by kittytoaster

[nitevision92]

Still didn't work for me. I found out about the bug before I tossed in the witch head to cure myself, but after I cured Vilkas and Farkas.

Did all of the above, including leaving the area, changing signs, save/load etc. and tested by sleeping. I still end up with all of the cons of lycanthropy and none of the advantages.

I wonder if I should slog it by foot to another region before going back to the stone. Or maybe I should toss the witch head in first.

Edited November 23, 2011 by nitevision92

[kittytoaster]

Still didn't work for me.

 

Odd, care to send me your savegame so I can look into the bits?

[email protected]

 

Got it fixed.

Edited November 27, 2011 by kittytoaster