Clan Tremere / Vampire society mod scripting request

[Galejro]

I work on a massive expansion for my Clan Tremere mod which will be called Vampire society mod. And I honestly suck at making scripts so if anyone could help I'd be very greatful.

 

I need the following scripts.

 

Script 1: the studium the thaumaturgie.

 

I need a script for an activator object like a vampire shrine that will grant you a completly new spell if you have a particular spell already learned and a particular set of 3 objects, and shows a text that confirms you recieving the new spell. And once you activate it and recieve the spell you can't do that again for that particular basic spell.

 

Example: you have "blood bolt" spell and If you activate the shrine with a sabercats eye and a black soul gem and blood bolt spelltome in inventory you recieve an "explosive blood bolt spell", a text confirming it, and a blockade from using the activator in reference to that "blood bolt" spell

 

Script 2: Blood Transmutator.

 

I need a script for an activator shrine or something that will make a particular set of ingredients for example human flesh/ heart + nightshade to turn into a potion.

[KingsGambit]

You can try these. They compile fine but may need some fine turning. Obviously the propertie need to be preset to the the various items to check for.

 

Scriptname SpellShrineScript extends objectreference

Ingredient Property ItemToCheck1 auto
Soulgem Property ItemToCheck2 auto
Book Property ItemToCheck3 auto

Spell Property SpellToCheck auto
Spell Property SpellToGive auto

Event OnActivate(ObjectReference ActionRef)
if(ActionRef == Game.GetPlayer())
	if(Game.GetPlayer().HasSpell(SpellToGive))
		Debug.Notification("You have already mastered all that this shrine can teach")
	elseif(Game.GetPlayer().HasSpell(SpellToCheck) && Game.GetPlayer().GetItemCount(ItemToCheck1) >= 1 && Game.GetPlayer().GetItemCount(ItemToCheck2) >= 1 && Game.GetPlayer().GetItemCount(ItemToCheck3) >= 1)
		Game.GetPlayer().AddSpell(SpellToGive, False)
		Debug.Notification("You have unlocked the secrets of the " + SpellToGive + " spell")
;			Game.GetPlayer().RemoveSpell(SpellToCheck)     ; Removes the original spell if desired
;			Game.GetPlayer().RemoveItem(ItemToCheck1, 1) ; Removes one of the item if you wish to do so
;			Game.GetPlayer().RemoveItem(ItemToCheck2, 1)
;			Game.GetPlayer().RemoveItem(ItemToCheck3, 1)
	else
		Debug.Notification("Nothing happens")
	endif
endif
EndEvent

 

And for the second, something like:

Scriptname MyPotionScript extends objectreference

Ingredient Property ItemToCheck1 auto
Ingredient Property ItemToCheck2 auto
Ingredient Property ItemToCheck3 auto
Potion Property MyPotion auto

Event OnActivate(ObjectReference ActionRef)
if(ActionRef == Game.GetPlayer())
	if(Game.GetPlayer().GetItemCount(ItemToCheck1) >= 1 && Game.GetPlayer().GetItemCount(ItemToCheck2) >= 1 && Game.GetPlayer().GetItemCount(ItemToCheck3) >= 1)
		Game.GetPlayer().RemoveItem(ItemToCheck1, 1) ; Removes one of the item
		Game.GetPlayer().RemoveItem(ItemToCheck2, 1) ; Removes one of the item
		Game.GetPlayer().RemoveItem(ItemToCheck3, 1) ; Removes one of the item
		Game.GetPlayer().AddItem(MyPotion, 1)
	else
		Debug.Notification("You lack the required ingredients")
	endif
endif
EndEvent

[Galejro]

Thanks