Trying to mod a quest, where can I find the spawning script for Goodsprings Powder Gangers

[dankaxolotl]

Hi, I'm trying to make a mod that would add another character to Joe Cobb's posse in the quest Ghost Town Gunfight, I've looked at all the scripts I could find, but I cannot seem to locate the script that spawns the 5 powder gangers so that I could add a 6th member (with the same AI Package as the rest). This is my first mod so I am fairly new to G.E.C.K.

[dubiousintent]

Just an idea: did you try checking the "Result Script" of dialog commiting to the fight? Might be in the Player's dialog response instead of one of Joe's lines.

 

-Dubious-

[dankaxolotl]

Just an idea: did you try checking the "Result Script" of dialog commiting to the fight? Might be in the Player's dialog response instead of one of Joe's lines.

 

-Dubious-

SetObjectiveCompleted VMS16 65 1
SetObjectiveDisplayed VMS16 70 1
ForceActiveQuest VMS16
GSVictorRef.SetUnconscious 1

SetAlly GoodspringsFaction PlayerFaction
SetAlly GoodspringsRingoAlliesFaction PlayerFaction
SetEnemy GoodspringsPowderGangFaction GoodspringsRingoAlliesFaction
SetEnemy GoodspringsPowderGangFaction PlayerFaction

if (GetObjectiveDisplayed VMS16 20) && (GetObjectiveCompleted VMS16 20 == 0)
SetObjectiveDisplayed VMS16 20 0
endif

if (GetObjectiveDisplayed VMS16 30) && (GetObjectiveCompleted VMS16 30 == 0)
SetObjectiveDisplayed VMS16 30 0
endif

if (GetObjectiveDisplayed VMS16 40) && (GetObjectiveCompleted VMS16 40 == 0)
SetObjectiveDisplayed VMS16 40 0
endif

if (GetObjectiveDisplayed VMS16 45) && (GetObjectiveCompleted VMS16 45 == 0)
SetObjectiveDisplayed VMS16 45 0
endif

if (GSJoeCobbRef.GetDead == 0)
GSJoeCobbRef.MoveTo JoeCobbPositionMarker
endif

if (VMS16.bTrudyHelp)
  if (GoodspringsSettler01Ref.GetDead == 0)
    GoodspringsSettler01Ref.MoveTo GSSettler01PositionMarker
  endif
  if (GoodspringsSettler02Ref.GetDead == 0)
    GoodspringsSettler02Ref.MoveTo GSSettler02PositionMarker
  endif
  if (GoodspringsSettler03Ref.GetDead == 0)
    GoodspringsSettler03Ref.MoveTo GSSettler03PositionMarker
  endif
  if (GoodspringsSettler04Ref.GetDead == 0)
    GoodspringsSettler04Ref.MoveTo GSSettler04PositionMarker
  endif
GoodspringsSettler01Ref.AddToFaction GoodspringsRingoAlliesFaction 1
GoodspringsSettler02Ref.AddToFaction GoodspringsRingoAlliesFaction 1
GoodspringsSettler03Ref.AddToFaction GoodspringsRingoAlliesFaction 1
GoodspringsSettler04Ref.AddToFaction GoodspringsRingoAlliesFaction 1
TrudyRef.AddToFaction GoodspringsRingoAlliesFaction 1
  if (TrudyRef.GetDead == 0)
    TrudyRef.MoveTo TrudyPositionMarker
    TrudyRef.AddItem WithAmmoNVSingleShotGunLoot 1
  endif
endif

Here is the full Result of VMS16 stage 70, I have pretty much picked apart this quest. Everything except where the PG spawns.

I will post a couple more short codes of interest.

Here is GSPowderGangTriggerScript

scn GSPowderGangTriggerScript

short bDoOnce

begin OnTriggerEnter player

	if bDoOnce == 0 && GetStageDone VMS16 70
		ShowWarning "Incoming powder gangers."
		GSPG01Ref.AddScriptPackage GSPGTravelPackage
		GSPG02Ref.AddScriptPackage GSPGTravelPackage
		GSPG03Ref.AddScriptPackage GSPGTravelPackage
		;GSPG04Ref.AddScriptPackage GSPGTravelPackage
		GSPG05Ref.AddScriptPackage GSPGTravelPackage
		GSPG06Ref.AddScriptPackage GSPGTravelPackage
		set bDoOnce to 1
	endif

end

 

Here is the quest script for Ghost Town Gunfight (VMS16)

scn VMS16QuestScript

short nGangerDeathCount
short nSettlerDeathCount
short bMetJoeCobb
short bSunnyHelp					; 1 = Player has Sunny's help vs. powder gang.
short bTrudyHelp					; 1 = Player has Trudy's help vs. powder gang.
short bChetHelp					; 1 = Player bartered with Chet to supply the militia.
short bPeteHelp					; 1 = Player is getting dynamite from Pete.
short bVictorHelp					; 1 = Victor has offered to help.
short Ambush						; 1 = Sneak 25+. Player arranges for an ambush of the powder gang.

short bJoeHelp						; 1 = Player agreed to kill Ringo for Joe.
short bJoeCobbGratitude		; 1 = Player helped Joe Cobb take over Goodsprings.

short bMoveGang					; 1 = Powder Gang allowed to move up the road.
short bGunFightStart				; 1 = Gunfight is underway.

short QuestComplete				; 1 = Complete, not Failed, state

begin GameMode

	if (TrudyRef.GetDead == 1)
		if (GetObjectiveDisplayed VMS16 20 == 1) && (GetObjectiveCompleted VMS16 20 == 0)
			SetObjectiveDisplayed VMS16 20 0
		endif
	endif

	if (GSChetRef.GetDead == 1)
		if (GetObjectiveDisplayed VMS16 30 == 1) && (GetObjectiveCompleted VMS16 30 == 0)
			SetObjectiveDisplayed VMS16 30 0
		endif
	endif

	if (EasyPeteRef.GetDead == 1)
		if (GetObjectiveDisplayed VMS16 40 == 1) && (GetObjectiveCompleted VMS16 40 == 0)
			SetObjectiveDisplayed VMS16 40 0
		endif
	endif

	if (DocMitchellRef.GetDead == 1)
		if (GetObjectiveDisplayed VMS16 45 == 1) && (GetObjectiveCompleted VMS16 45 == 0)
			SetObjectiveDisplayed VMS16 45 0
		endif
	endif

	if (GetStageDone VMS16 70) && (GetQuestCompleted VMS16 == 0) && (bGunFightStart == 0)

		set bGunFightStart to 1
				
		GSJoeCobbRef.AddScriptPackage GSPGTravelPackage

		if (bTrudyHelp == 0)
			GoodspringsSettler02Ref.AddScriptPackage GoodspringsFleePackage
			GoodspringsSettler03Ref.AddScriptPackage GoodspringsFleePackage
			GoodspringsSettler04Ref.AddScriptPackage GoodspringsFleePackage
		endif

	endif

	if (GetObjectiveDisplayed VMS16 70 == 1) && (GetObjectiveCompleted VMS16 70 == 0)
		if nGangerDeathCount >= 6
			SetObjectiveCompleted VMS16 70 1
			SetStage VMS16 100
		endif
	endif

end

One line sticks out to me

short bMoveGang					; 1 = Powder Gang allowed to move up the road.

Where could I find this script(?) that moves them up the road

 

 

 

[UnvalidUserName]

I assume all the power rangers already exist in the game but are initially disabled. Check if GSPGTravelPackage enables the entity it gets attached to

[dankaxolotl]

yep, that was it, thank you