SSE Base script error.

[scoobnut]

I have been trying to port Tairensouls warpaints from LE to SE.

I have got textures ported and esp updated but when I run my game I get a racemenu error saying invalid base scripts {error code 2}

I am new to this and so missing something, any help would be appreciated.

[ReDragon2013]

That means your installed script version of RaceMenu should be updated. The base script is "RaceMenuBase.psc" as source and "RaceMenuBase.pex" as executable.

    ; RaceMenu version check
    If RaceMenuBase.GetScriptVersionRelease() < RACEMENUBASE_SCRIPT_VERSION
        startupError += ("Invalid RaceMenuBase script version detected (" + RaceMenuBase.GetScriptVersionRelease() + ") expected (" + RACEMENUBASE_SCRIPT_VERSION + "). Please update your base script. ")
        errorCodes += "(2)"            ; ***
    Endif

RaceMenu code snippet

 

Scriptname RaceMenu extends RaceMenuBase

Event OnGameReload()
    OnStartup()                        ; ***

    LoadDefaults()

    ; Reload player settings
    LoadHair()
    LoadTints()
    UpdateTints()
    SendModEvent("RSM_LoadPlugins")
EndEvent


Function OnStartup()                ; ***
    RegisterForMenu(RACESEX_MENU)

    RegisterEvents()

    Utility.SetINIFloat("fPlayerBodyEditDistance:Interface", 190.0)
    Utility.SetINIFloat("fPlayerFaceEditDistance:Interface", 70.0)

    ; Re-initialization in case of init failure?
    Reinitialize()

    string startupError = ""
    string errorCodes = ""
    
    ; SKSE Version Check
    If SKSE.GetVersionRelease() < SKSE_RELEASE_VERSION
        startupError += ("You are running SKSE Version " + SKSE.GetVersion() + "." + SKSE.GetVersionMinor() + "." + SKSE.GetVersionBeta() + "." + SKSE.GetVersionRelease() + " expected "+SKSE_MAJOR_VERSION+"."+SKSE_MINOR_VERSION+"."+SKSE_BETA_VERSION+"."+SKSE_RELEASE_VERSION+" or greater. ")
        errorCodes += "(0)"
    Endif
    If SKSE.GetVersionRelease() != SKSE.GetScriptVersionRelease()
        startupError += ("SKSE script version mismatch detected (" + SKSE.GetScriptVersionRelease() + ") expected (" + SKSE.GetVersionRelease() + "). Please reinstall your SKSE scripts to match your version. ")
        errorCodes += "(1)"
    Endif

    ; RaceMenu version check
    If RaceMenuBase.GetScriptVersionRelease() < RACEMENUBASE_SCRIPT_VERSION
        startupError += ("Invalid RaceMenuBase script version detected (" + RaceMenuBase.GetScriptVersionRelease() + ") expected (" + RACEMENUBASE_SCRIPT_VERSION + "). Please update your base script. ")
        errorCodes += "(2)"            ; ***
    Endif

    ; Plugin version check
    int chargenVersion = SKSE.GetPluginVersion("CharGen")
    int nioverrideVersion = SKSE.GetPluginVersion("NiOverride")

    int chargenScriptVersion = CharGen.GetScriptVersion()
    int nioverrideScriptVersion = NiOverride.GetScriptVersion()

    ; Plugins not installed
    If nioverrideVersion == 0
        startupError += ("NiOverride plugin not detected, various features may be unavailable. ")
        errorCodes += "(3)"
    Endif
    If chargenVersion == 0
        startupError += ("CharGen plugin not detected, various features may be unavailable. ")
        errorCodes += "(4)"
    Endif

    ; Scripts not installed
    If nioverrideScriptVersion == 0
        startupError += ("NiOverride script not detected, various features may be unavailable. ")
        errorCodes += "(5)"
    Endif
    If chargenScriptVersion == 0
        startupError += ("CharGen script not detected, various features may be unavailable. ")
        errorCodes += "(6)"
    Endif

    ; Plugin installed but wrong version
    If nioverrideVersion > 0 && nioverrideVersion < NIOVERRIDE_VERSION
        startupError += ("Invalid NiOverride plugin version detected (" + nioverrideVersion + ") expected (" + NIOVERRIDE_VERSION + "). ")
        errorCodes += "(7)"
    Endif
    If chargenVersion > 0 && chargenVersion < CHARGEN_VERSION
        startupError += ("Invalid CharGen plugin version detected (" + chargenVersion + ") expected (" + CHARGEN_VERSION + "). ")
        errorCodes += "(8)"
    Endif

    ; Plugins installed but scripts wrong version
    If nioverrideScriptVersion > 0 && nioverrideScriptVersion < NIOVERRIDE_SCRIPT_VERSION
        startupError += ("Invalid NiOverride script version detected (" + nioverrideScriptVersion + ") expected (" + NIOVERRIDE_SCRIPT_VERSION + "). ")
        errorCodes += "(9)"
    Endif
    If chargenScriptVersion > 0 && chargenScriptVersion < CHARGEN_SCRIPT_VERSION
        startupError += ("Invalid CharGen script version detected (" + chargenScriptVersion + ") expected (" + CHARGEN_SCRIPT_VERSION + "). ")
        errorCodes += "(10)"
    Endif

    If startupError != ""
        Debug.MessageBox("RaceMenu Error(s): " + startupError + "\nError Codes: " + errorCodes)
    Endif

    _targetRoot = RACESEX_MENU
    _targetMenu = MENU_ROOT
    _targetActor = _playerActor
    _targetActorBase = _targetActor.GetActorBase()
EndFunction

 

 

 

LE is using 32-bit with SKSE, SE is using 64-bit with SKSE64. Racemenu should also have two different mods one for Skyrim LE and one for Skyrim SE.

Edited April 27, 2021 by ReDragon2013

[scoobnut]

Thanks for your reply. I'm using Skyrim SE but the mod I wont to port is for LE. I read that scripts shouldn't be a problem but apparently they are. What do I do to update scripts for SE?