Is there a way to …

[pepperman35]

… prevent the Wait component from showing up when a play sits in a chair. I am using a script to force a player into the furniture and then disable player controls so they will stay seated uptil released. What I’d like to also do is hide (prevent) the T) Wait from being displayed.

Scriptname SermonSceneSupportScript extends Quest
; / Script placed on the pastors dialogue quest

; ╔═════════════════════════════════════════════════╗
; ║                   Properties                    ║
; ╚═════════════════════════════════════════════════╝
Quest Property FO4_SummonCongregationQuest Auto Const Mandatory
GlobalVariable Property FO4_PastorSummonState Auto Const Mandatory
ReferenceAlias Property Alias_FemaleWorshiper Auto Const Mandatory
ReferenceAlias Property Alias_PastorAllen Auto Const Mandatory
ReferenceAlias Property Alias_Player Auto Const Mandatory
ReferenceAlias Property FemaleWorshipperOrigin Auto Const Mandatory
ObjectReference Property FO4_FemaleWorshipperMarker Auto Const Mandatory
ObjectReference Property FO4_MusicMarker01 Auto Const Mandatory
ObjectReference Property FO4_PlayerPew Auto Const Mandatory
Sound Property FO4_ChurchMusic01 Auto Const Mandatory
InputEnableLayer Property SermonInputLayer Auto Hidden

Function ForcePlayertoSit()
; After requesting a word from the Lord this function is called to place two
; invisible players into the scence for sound bytes.  The function will also
; force the player into a chuch pew and disable their controls
; Move the female NPC worshipper into the scene and turn them invisible
	Alias_FemaleWorshiper.GetReference().moveto(FO4_FemaleWorshipperMarker)
	Alias_FemaleWorshiper.GetActorReference().SetAlpha(0.0)
;
; Move the player and force him into a church pew
;
	Alias_Player.GetReference().moveto(FO4_PlayerPew)
;
; Disable player controls so that he remains seated throughout the sermon
;
	SermonInputLayer = InputEnableLayer.Create()
	SermonInputLayer.DisablePlayerControls()
	game.ForceFirstPerson()
; Memo: Not sure if the next two lines are needed as we are forcing the player into the pew
; via moveto.  Could not get the travel/sit AI package to work.
	game.SetPlayerAIDriven(true)
	Alias_Player.GetActorReference().EvaluatePackage()
; Give a little bit of time to ensure the player get loaded into the pew then block activation
	Utility.Wait(1.0)
	FO4_PlayerPew.BlockActivation(true, true)
EndFunction

Function DismissCongregration()
; This function is called after the pastor finishes his sermon.  It serves to
; dismiss the congregration, return the invisible worshippers to their 
; holding cell and returns control ; to the player
;
; Dismiss the congregration
;
	FO4_SummonCongregationQuest.SetStage(20)
;
; Play some church music
;
	FO4_ChurchMusic01.play(FO4_MusicMarker01)
;
; Return the pastor to his house
;
	FO4_PastorSummonState.SetValue(0 as float)
	Alias_PastorAllen.GetActorReference().EvaluatePackage()
;
; Return NPC stand-in workshipers to their holding cell
;
	Alias_FemaleWorshiper.GetReference().moveto(FemaleWorshipperOrigin.GetReference())
	Alias_FemaleWorshiper.GetActorReference().SetAlpha(1.0)
;enable player controls
	SermonInputLayer.EnablePlayerControls()
	Game.SetPlayerAIDriven(false)
	SermonInputLayer.delete()
	SermonInputLayer = None
	FO4_PlayerPew.BlockActivation(false)
EndFunction

[niston]

Isnt there a keyword to hide the wait prompt?

 

EDIT: ah yes, FurnitureCantWait

[pepperman35]

Thank you sir!

[LarannKiar]

Might be a bit off-topic but for this concept, I wanted to mention that FurnitureRef.SetNoFavorAllowed() prevents NPCs (companions, sandboxing settlers, etc.) from sitting in the furniture if that matters.

Edited March 30, 2023 by LarannKiar