SSE Fishing-Creation-Club Draugr Weapons

[scorrp10]

I am not really sure what you mean by 'removing those quests'. They are part of Fishing DLC and as long as it is in your load order, the quests are there. If you mean you ran Stop() on that quest, it is a seriously bad idea since that quest has an OnPlayerLoadGame event checking for version updates, and killing that quest in a save game will kill its ability to react to released updates/fixes. Not that there is a big likelihood, but still. Not that it does much in your case since that script runs only at the very start of a new playthrough.

 

This particular function (RunSetupBaseGame) is called from OnInit(), so it really runs only when a new game is started - or if a saved game is loaded the first time after Fishing DLC has been added. And in that function sets up a lot of other fishing-related stuff. You absolutely should NOT interfere with it.

 

What you CAN do for your own, especially assuming you want to upload your mod for other's use, is to counteract that specific activity. You create a start game enabled quest, with player alias and script attached to it. If your mod already has a start game quest, can just stick it in there. That script should have an OnInit() and OnPlayerLoadGame() events, both calling RegisterForSingleUpdate(30), and then an OnUpdate() function. The idea is to run your thing about 30 seconds after new game is started or loaded.

 

Something like:

scriptName FishingCounterScript extends ReferenceAlias

LeveledItem Property LItemDraugr02Weapon2H Auto
LeveledItem property LItemDraugr02Weapon1H Auto
Int FishingIndex

Event OnInit()
    RegisterForSingleUpdate(30)
EndEvent

Event OnPlayerLoadGame()
    RegisterForSingleUpdate(30)
EndEvent

Event OnUpdate()
    ;  The easy option:
    ;  This will remove any entry added by any script.
    ;  But if you are doing your own distributor that alters these LIs, Revert() will clobber your additions as well 
    LItemDraugr02Weapon2H.Revert()
    LItemDraugr02Weapon1H.Revert()

    ;  The more precise option = only disable forms defined in Fishing DLC.
    FishingIndex = Math.LeftShift(Game.GetModByName("ccBGSSSE001-Fish.esm"), 24)
    ClearFishing(LItemDraugr02Weapon2H)
    ClearFishing(LItemDraugr02Weapon1H)
EndEvent

Function ClearFishing(LeveledItem _li)
    Int _idx = _li.GetNumForms()
    While _idx > 0
        _idx = _idx - 1
        Form _form = _li.GetNthForm(_idx)
        If _form && Math.LogicalAnd(_form.GetFormID(), FishingIndex) == FishingIndex
            If _li.GetNthCount(_idx) > 0
                Debug.Trace("Form: " + _form + " (" + _form.GetName() + ") Added by Fishing DLC, disabling")
                ; Now LevelledItem does not have a RemoveForm method, so we have to do it like this:
                _li.SetNthCount(_idx, 0)
            EndIf
        EndIf
    EndWhile
EndFunction

[LusterCab]

bro my head is not functioning correctly this is too much work for me :laugh:

first tried to simply uncheck "start game enabled" option for the quest, and started a new game. but this did nothing. then i just went into xedit and deleted the entire quest tree within the fishing CC plugin. this also did nothing and is how i am sure the weapons script is not attached to any quests. haha

 

but anyway, this seems like too much work for something which should be simple. this CC DLC is very intrusive. is there perhaps some other way to remove all of this without much effort, or perhaps some better way to just delete things directly from the plugin using xedit?

im not really interested in sharing my mods with anyone but a few friends, but i did plan on hosting my mods here on the nexus since its convenient. but now im thinking to just host it myself on gdrive or steam

[7531Leonidas]

There is this mod ( https://www.nexusmods.com/skyrimspecialedition/mods/58783 ) - it also has a version to remove the 4 'free' CC mods.

[scorrp10]

The CC Fishing mod is part of the standard Skyrim SE install package. Sure, you can delete it for yourself, and tell whoever you want to share the mod with to delete it. But next time Steam checks it for update, you'll get it right back. So really, it is in your best interest to work this out in a way that does not rely on removing this mod.

first tried to simply uncheck "start game enabled" option for the quest, and started a new game. but this did nothing. then i just went into xedit and deleted the entire quest tree within the fishing CC plugin. this also did nothing and is how i am sure the weapons script is not attached to any quests. haha

Impossible. The script runs when player is initialized as an Alias to that quest, which ONLY happens when this quest runs. Which means that you either failed to properly apply your changes to the plugin file, or Steam somehow determined that the file was messed with, and reloaded it.

 

The script that I gave - you just need to attach it to something and make sure it runs not right away on new game start, but maybe half a minute later or at any time after that. It will clear just those draugr weapons without affecting anything else.

[LusterCab]

i had to double check, but i am 100% certain all the quests from the fishing CC plugin have been deleted.

the CC weapons still spawn on the draugr without the quest.

 

100% sure the quests are gone

100% sure the correct plugin with the deleted quests are loaded

100% sure im starting a new game and not using an old save file