Year One .Pak files

[EveBishop]

As the title implies, this is the Year One edition, so there is probably some compatibility issues, but if someone figures out a strategy to unpak it, this would be a good place to discuss it.

 

 

 

So, ive tried 3 different extraction programs, and when i try to extract any of the .pak files (which hold allllll of the data to mod) they always come back with the same error. Two, techincally.

 

Error: the compressed zlib/deflate input is wrong or incomplete (-3)

Error: there is an error with the decompression

the returned output size is negative (-1)

Extracting the single breakdown .pak yields the first file that it failed to extract, then full stop and it pretends the extraction was successful.

Does anyone have any clues for me?

[tonicmole]

Same problem here. When I unpack the Character pack it just creates a partial file structure with an empty Crow folder, and throws the -1 error.

[angelsavior9mm]

Download quickbms http://aluigi.altervista.org/quickbms.htm

 

Create an new .txt file with whatever name and just copy/paste the entire following script in it

(I did NOT create the script or program, only know of them)

# ZIP files (alternative way) 0.1
#   get end of directory and parses central directory
# script for QuickBMS http://quickbms.aluigi.org

goto -0x16
idstring "PK\x05\x06"
        get disk_num        short
        get disk_start      short
        get central_entries short
        get central_entries short
        get central_size    long
        get central_offset  long
        get comm_len        short
        getdstring comment  comm_len

for i = 0 < central_entries
    goto central_offset
    idstring "PK\x01\x02"
        get ver_made        short
        get ver_need        short
        get flag            short
        get method          short
        get modtime         short
        get moddate         short
        get crc             long
        get comp_size       long
        get uncomp_size     long
        get name_len        short
        get extra_len       short
        get comm_len        short
        get disknum         short
        get int_attr        short
        get ext_attr        long
        get rel_offset      long
        getdstring name     name_len
        getdstring extra    extra_len
        getdstring comment  comm_len
    savepos central_offset

    goto rel_offset
    idstring "PK\x03\x04"
        get ver             short
        get flag            short
        get method          short
        get modtime         short
        get moddate         short
        get crc             long
        get comp_size       long
        get uncomp_size     long
        get name_len        short
        get extra_len       short
        getdstring name     name_len
        getdstring extra    extra_len
        savepos offset

        if method == 0
            Log name offset uncomp_size
        else
            if method == 8
                ComType zlib
            elif method == 1
                ComType unshrink
            elif method == 6
                ComType explode
            elif method == 9
                ComType deflate64
            elif method == 12
                ComType bzip2
            elif method == 14
                ComType lzmaefs
            elif method == 13
                ComType XMemDecompress
            elif method == 21
                ComType XMemDecompress
            elif method == 64
                ComType darksector
            elif method == 98
                ComType ppmd
            elif method == 99
                print "this script doesn't support AES encryption"
                cleanexit
            else
                print "unsupported compression method %method%"
                cleanexit
            endif
            CLog name offset comp_size uncomp_size
        endif
next i

Run quickbms, it'll ask for the script first, select the txt file you made containing above script, then it asks for the archive, which is the .pak file, and finally select the save location. Voila, files extracted.

[tonicmole]

Works like a charm! Well done.