Cheat amulet

[BalorC23]

I was wondering could someone make an amulet that adds 20 skill points to sneak security atletics and adds 100 points to acrobatics. Also this part is just an option but could it also add sunlight immunity and makes people like you.

[tyreil829]

in other words

 

Fortry Sneak 20

Fortry Security 20

Foritry Atlectics 20

Foritry Acrobatics 100

Script effect: Sunlight Immunity

Fortry Personailly 30

 

with the sunlight immunity its easier to feed if your a vampire makes life easier but from the rest above is that what you want? a enchant Amulet?

 

Col John Sheppard

[BalorC23]

yep I would like all that on an amulet but the sun light thing is optional

[Reepimeister]

PM me an e-mail address and I'll send it your way.

[LoginToDownload]

You should be able to do this by yourself if you have the CS. Most of the work is in the Sunlight Immunity, but it's definitely doable. Since it's for personal use and to keep it (comparatively) simple, it won't be compatible with any Vampire overhauls and will cause trouble if you wear it while being cured of vampirism. OBSE could get around those (Quite easilly, in fact), but none of it should be a big problem.

 

Setting up the Sunlight Resistance:

First, select Magic/Spell in the object window and go to the very bottom of the list. Open up Vampirism50, change the ID to something else, (this tutorial will use "MyVampirism50Alt") right click on the "Sun Damage" effect, and remove it. When you save it by clicking "OK", make sure you say "Yes" to "Create a new form?" The result should essentially be a copy of Vampirism50 with no Sun Damage effect. Repeat for Vampirism75 and Vampirism100.

 

Now it's time for scripting. Open up the Gameplay tab and select "Edit Scripts..." Click on Script, then New. Go to the drop-down box at the top and select "Magic Effect" so it will appear as an option for the Script Effect we'll put in the enchantment later. The script itself should go something like this...

 

scn MyAmuletSunImmunityScript
;scn stands for Scriptname.  The first line of every script has to name it.

Begin ScriptEffectUpdate
;All scripts need to be in a Begin/End block, which determined when they run.
;ScriptEffectUpdate blocks can only be used for Magic Effect scripts, and run every frame the effect is active.

 if (IsSpellTarget Vampirism25 && (IsSpellTarget MyVampirism50Alt || IsSpellTarget MyVampirism75Alt || IsSpellTarget MyVampirism100Alt) )
;The contents of an If/Endif loop only run if the loop's conditions are true.
;In this case, if the holder is subject to the Vampirism25 effect *and* one of our "Alts".

	  message " "
	  message " "
	 ;If two of the same message are in a row, any "queue" of messages after it vanishes.
	 ;This is to prevent annoying messages when putting the amulet on and taking it off.

	  RemoveSpell MyVampirism50Alt
	  RemoveSpell MyVampirism75Alt
	  RemoveSpell MyVampirism100Alt
	 ;Clearing out any Vampirism Alts previously in effect

 elseif (IsSpellTarget Vampirism50)
	 ;Elseif blocks also require the previous part(s) of the if-loop to not have had its conditions met.
	 ;Essentialy it means "Otherwise, if..."

	  message " "
	  message " "

	  RemoveSpell MyVampirism75Alt
	  RemoveSpell MyVampirism100Alt
	  RemoveSpell Vampirism50
	  AddSpell MyVampirism50Alt
	 ;We don't need to specifically state *who* has the spells removed and added...
	 ;...Since Magic Effect scripts assume you're talking about their subject if not specified.

 elseif (IsSpellTarget Vampirism75)

	  message " "
	  message " "
	  RemoveSpell MyVampirism50Alt
	  RemoveSpell MyVampirism100Alt
	  RemoveSpell Vampirism75
	  AddSpell MyVampirism75Alt

 elseif (IsSpellTarget Vampirism100)
	  message " "
	  message " "
	  RemoveSpell MyVampirism50Alt
	  RemoveSpell MyVampirism75Alt
	  RemoveSpell Vampirism100
	  AddSpell MyVampirism100Alt
 endif

end

Begin ScriptEffectFinish
;ScriptEffectFinish blocks run when the effect ends.
;Here we'll just clean up by swapping our "Alt" effects back for the standard ones.

 if (IsSpellTarget MyVampirism50Alt)
	  message " "
	  message " "
	  RemoveSpell MyVampirism50Alt
	  AddSpell Vampirism50
 elseif (IsSpellTarget MyVampirism75Alt)
	  message " "
	  message " "
	  RemoveSpell MyVampirism75Alt
	  AddSpell Vampirism75
 elseif (IsSpellTarget MyVampirism100Alt)
	  message " "
	  message " "
	  RemoveSpell MyVampirism100Alt
	  AddSpell Vampirism100
 endif

end

 

 

Enchanting an Amulet:

Don't worry, the hard part is over. Go back to the Object Window and select Magic/Enchantment. Right-click on the list and select new. For the purposes of this tutorial, the new enchantment's ID will be MyAmuletEnchantment, but you're welcome to call it whatever you want. Set the type to Apparel, and right-click in the Effects list (though it's empty at the moment) selecting "New". Adding the Fortify effects should be pretty intuitive. Select the effect type (In this case, Fortify Skill). You'll also need to select the right ActorVal you want and the magnitude. Duration should be left at 0.

 

Once you're finished with the Fortify effects, create one more. Set its effect to Script Effect. This should open up a new box at the bottom to control the Script Effect specifics. The only really important part is the Script, for which you should naturally pick MyAmuletSunImmunityScript. If it's not available as an option, open it up again in Gameplay/Edit Scripts and make sure the drop-down box at the top reads "Magic Effect". You'll also probably want to give it an Effect Name aside from Script Effect, like Sunlight Immunity.

 

Save your new enchantment and select Items/Clothing in the Object Window. It's alphabetically ordered, so scroll down to Jewelry. Open up your favorite of the JewelryAmulet or JewelryNecklace items and change its ID to something like "MyAmulet". Feel free to change its name, weight and value to whatever you want and/or set it as a Quest Item so you can't drop it, but make sure it stays playable. Select your Enchantment in the Enchanting drop-down box. Of course, as you save your new necklace, make sure you do so as a new form instead of over-writing the old necklace.

 

 

Placing your Amulet in the World:

There are lots of ways of going about adding your amulet to the game proper, but I'll cover the two most standard ones for cheat items. The first method is just to place it somewhere. If necessary, a tutorial for navigating the Render Window can be found here.

 

The second method takes a bit more work, (Assuming you wouldn't need to learn how to place objects and move around in the render window. It's a bit disorienting at first) and is adding the item to the player directly. Go into Character/Quest, right-click on the list to the left, and create a new quest. Name it whatever you want (MyAmuletQuest for the purposes of this tutorial). Check "Start Game Enabled", and open up a different quest. Just about any should do. Under Quest Conditions, right-click the GetIsPlayableRace == 1 condition and select "Copy Condition". Now go back to your quest, right-click on its quest conditions list, and select "Paste Conditions".

Leave the Quest for now and go back to Gameplay/Edit Scripts and create a new one. This time, set the drop-down box to Quest. The contents should go like this...

 

scn MyAmuletQuestScript

Begin GameMode
player.AddItem MyAmulet
StopQuest MyAmuletQuest
end

That was much simpler than the last script. GameMode blocks run with varying speed depending on the object, but about every four seconds for Quest scripts. When it runs, it'll give the player the amulet and disable itself. Go back to your quest and set the Script to MyAmuletQuestScript, and you're done.

[Reepimeister]

Wow.

 

I totally just did what you said, before you posted it. Like. Word to word.

 

The only difference is that I used doonce variables to stop the annoying messages. Didn't know about that message queue malarky. Thanks. :)

 

Also, I used the global variable for vampirism to determine which spell is on the player at he time.

[LoginToDownload]

I suppose there aren't many ways of going about it without OBSE. :)

[BalorC23]

man I did it like you said but every time I try to save the script for the quest it keeps saying script 'MyAmuletQuestScript',line 4:

Missing parameter Count

Compiled script not saved

[LoginToDownload]

I'm an idiot... That should be "AddItem MyAmulet 1". You need to specify the number of the item you want added... :sweat:

[nosisab]

man I did it like you said but every time I try to save the script for the quest it keeps saying script 'MyAmuletQuestScript',line 4:

Missing parameter Count

Compiled script not saved

LoginToDownload, wonderful and rich tutorial, kudos

 

BalorC23 by a "lapso" the number of items was missed, just ad 1 after the command, this way:

 

player.AddItem MyAmulet 1

 

Edit: LoginToDownload, mentioning the function was more a pretext to say your tuto worthy a kudos, thx, posted same time as your's reply :)